Abstract

Special cases may require special non-equidistant but stepwise constant distributions. These could be created with this function rww().

Appendix – Rww Code

Please read my Disclaimer.

Option Explicit

Function rww(ParamArray w() As Variant) As Double
'Produces random numbers with defined widths & weights
'Rww expects a vector of n random widths and
'weightings of type double and returns a random number of type double.
'This random number will lie in the given n-width-range of the
'(0,1)-intervall with the given likelihood of the n weightings.
'Source (EN): http://www.sulprobil.com/rww_en/
'Source (DE): http://www.bplumhoff.de/ww_de/
'(C) (P) by Bernd Plumhoff 06-Aug-2004 PB V0.50
'Examples:
'a) rww(1,0,1,1,8,0) will return a random number between 0.1 and 0.2
'b) rww(5,2,5,1) will return a random number between 0 and 0.5 twice as
'   often as a random number between 0.5 and 1.
'c) rww(1/3,0,1/3,1,1/3,0) will return a random number between
'   0.33333333333333 and 0.66666666666666.
'd) rww(5,15.4,3,7.7,2,0) would return a random value between
'   0 and 0.8, first 5 deciles with double likelihood than decile 6-8.

Dim i As Long
Dim swidths As Double
Dim sw As Double

If (UBound(w) + 1) Mod 2 <> 0 Then
    rww = -2     'No even number of arguments: Error
    Exit Function
End If

ReDim swidthsi(0 To (UBound(w) + 1) / 2 + 1) As Double
ReDim swi(0 To (UBound(w) + 1) / 2 + 1) As Double
ReDim weights(0 To (UBound(w) + 1) / 2) As Double
ReDim widths(0 To (UBound(w) + 1) / 2) As Double

    swidths = 0#
    sw = 0#
    swi(0) = 0#
    swidthsi(0) = 0#
    For i = 0 To (UBound(w) - 1) / 2
        If w(2 * i) < 0# Then     'A negative width is an error
            rww = -3#
            Exit Function
        End If
        widths(i) = w(2 * i)
        swidths = swidths + widths(i)
        swidthsi(i + 1) = swidths
        If w(2 * i + 1) < 0# Then 'A negative weight is an error
            rww = -1#
            Exit Function
        End If
        weights(i) = w(2 * i + 1)
        If widths(i) > 0# Then
            sw = sw + weights(i)
        End If
        swi(i + 1) = sw
    Next i
    rww = sw * Rnd
    'i = (UBound(w) - 1) / 2 + 1     'i already equals (UBound(w) - 1) /
                                    '2 + 1, you may omit this statement.
    Do While rww < swi(i)
        i = i - 1
    Loop
    
    rww = (swidthsi(i) + (rww - swi(i)) / weights(i) * widths(i)) / swidths

End Function